का उपयोग कर/ताज़ा संबंधपरक लटकता

धारणा: आप एक शब्द दस्तावेज़ के साथ दो लटकती सामग्री नियंत्रण. दोनों के लिए टैग के नाम पर सेट है: ccType और ccSelection.

में वर्ग मॉड्यूल की ThisDocument आप निम्नलिखित कोड को रखें:

Option Explicit

Private Sub Document_ContentControlOnExit(ByVal ContentControl As ContentControl, Cancel As Boolean)
If ContentControl.Tag = "ccType" Then
    fillccSelection ContentControl.Range.Text
End If
End Sub

Private Sub fillccSelection(valueType As String)

Dim cc As ContentControl
Set cc = ThisDocument.SelectContentControlsByTag("ccSelection")(1)

If cc.Title <> valueType Then
    With cc
        .Title = valueType  'set title to current type so that we now if coming here next time
        .Range.Text = vbNullString  'clear content as it has to change with new values
        With .DropdownListEntries
            .Clear
            Select Case valueType
                Case "Numbers"
                    cc.SetPlaceholderText Text:="Please select a number"
                    .Add "1"
                    .Add "2"
                    .Add "3"

                Case "Letters"
                    cc.SetPlaceholderText Text:="Please select a letter"
                    .Add "A"
                    .Add "B"
                    .Add "C"
            End Select
        End With
    End With
End If
End Sub

जब भी आप मूल्य में परिवर्तन की सामग्री को नियंत्रित (ccType) और बाहर निकलें यह ContentControlOnExit निकाल दिया है.

यदि आप "छोड़" ccType (और नहीं ccSelection) fillccSelection कहा जाता है, से गुजर रहा है के मूल्य में चयनित ccType.

यदि इस प्रकार अभी तक नहीं है के लिए सेट ccSelection, लटकती प्रविष्टियों सेट कर रहे हैं के अनुसार चयनित प्रकार ।